From 7d051302637e7c3ad06ff3701b437f8c12cef5c1 Mon Sep 17 00:00:00 2001
From: Anonymous Maarten <[EMAIL REDACTED]>
Date: Fri, 25 Oct 2024 15:11:32 +0200
Subject: [PATCH] cmake touches, add ci, add sym, SDL declspecs
---
.github/actions/setup-ninja/action.yml | 62 ++++
.github/workflows/main.yml | 60 ++++
CMakeLists.txt | 199 +++++++++----
cmake/PrivateSdlFunctions.cmake | 355 +++++++++++++++++++++++
cmake/SDL_gpu_shadercrossConfig.cmake.in | 45 +++
cmake/sdl-gpu-shadercross.pc.in | 13 +
include/SDL_gpu_shadercross.h | 47 ++-
src/SDL_gpu_shadercross.c | 16 +-
src/SDL_gpu_shadercross.sym | 18 ++
src/version.rc | 38 +++
10 files changed, 757 insertions(+), 96 deletions(-)
create mode 100644 .github/actions/setup-ninja/action.yml
create mode 100644 .github/workflows/main.yml
create mode 100644 cmake/PrivateSdlFunctions.cmake
create mode 100644 cmake/SDL_gpu_shadercrossConfig.cmake.in
create mode 100644 cmake/sdl-gpu-shadercross.pc.in
create mode 100644 src/SDL_gpu_shadercross.sym
create mode 100644 src/version.rc
diff --git a/.github/actions/setup-ninja/action.yml b/.github/actions/setup-ninja/action.yml
new file mode 100644
index 0000000..b5d5fad
--- /dev/null
+++ b/.github/actions/setup-ninja/action.yml
@@ -0,0 +1,62 @@
+name: 'Setup ninja'
+description: 'Download ninja and add it to the PATH environment variable'
+inputs:
+ version:
+ description: 'Ninja version'
+ default: '1.12.1'
+runs:
+ using: 'composite'
+ steps:
+ - name: 'Calculate variables'
+ id: calc
+ shell: sh
+ run: |
+ case "${{ runner.os }}-${{ runner.arch }}" in
+ "Linux-X86" | "Linux-X64")
+ archive="ninja-linux.zip"
+ ;;
+ "Linux-ARM64")
+ archive="ninja-linux-aarch64.zip"
+ ;;
+ "macOS-X86" | "macOS-X64" | "macOS-ARM64")
+ archive="ninja-mac.zip"
+ ;;
+ "Windows-X86" | "Windows-X64")
+ archive="ninja-win.zip"
+ ;;
+ "Windows-ARM64")
+ archive="ninja-winarm64.zip"
+ ;;
+ *)
+ echo "Unsupported ${{ runner.os }}-${{ runner.arch }}"
+ exit 1;
+ ;;
+ esac
+ echo "archive=${archive}" >> ${GITHUB_OUTPUT}
+ echo "cache-key=${archive}-${{ inputs.version }}-${{ runner.os }}-${{ runner.arch }}" >> ${GITHUB_OUTPUT}
+ - name: 'Restore cached ${{ steps.calc.outputs.archive }}'
+ id: cache-restore
+ uses: actions/cache/restore@v4
+ with:
+ path: '${{ runner.temp }}/${{ steps.calc.outputs.archive }}'
+ key: ${{ steps.calc.outputs.cache-key }}
+ - name: 'Download ninja ${{ inputs.version }} for ${{ runner.os }} (${{ runner.arch }})'
+ if: ${{ (!steps.cache-restore.outputs.cache-hit || steps.cache-restore.outputs.cache-hit == 'false') }}
+ shell: pwsh
+ run: |
+ Invoke-WebRequest "https://github.com/ninja-build/ninja/releases/download/v${{ inputs.version }}/${{ steps.calc.outputs.archive }}" -OutFile "${{ runner.temp }}/${{ steps.calc.outputs.archive }}"
+ - name: 'Cache ${{ steps.calc.outputs.archive }}'
+ if: ${{ (!steps.cache-restore.outputs.cache-hit || steps.cache-restore.outputs.cache-hit == 'false') }}
+ uses: actions/cache/save@v4
+ with:
+ path: '${{ runner.temp }}/${{ steps.calc.outputs.archive }}'
+ key: ${{ steps.calc.outputs.cache-key }}
+ - name: 'Extract ninja'
+ shell: pwsh
+ run: |
+ 7z "-o${{ runner.temp }}/ninja-${{ inputs.version }}-${{ runner.arch }}" x "${{ runner.temp }}/${{ steps.calc.outputs.archive }}"
+ - name: 'Set output variables'
+ id: final
+ shell: pwsh
+ run: |
+ echo "${{ runner.temp }}/ninja-${{ inputs.version }}-${{ runner.arch }}" >> $env:GITHUB_PATH
diff --git a/.github/workflows/main.yml b/.github/workflows/main.yml
new file mode 100644
index 0000000..6ca124f
--- /dev/null
+++ b/.github/workflows/main.yml
@@ -0,0 +1,60 @@
+name: Build
+
+on: [push, pull_request]
+
+jobs:
+ Build:
+ name: ${{ matrix.platform.name }}
+ runs-on: ${{ matrix.platform.os }}
+
+ defaults:
+ run:
+ shell: ${{ matrix.platform.shell }}
+
+ strategy:
+ fail-fast: false
+ matrix:
+ platform:
+ - { name: Windows (MSVC), os: windows-2019, shell: sh, msvc: true }
+ - { name: Windows (mingw64), os: windows-latest, shell: 'msys2 {0}', msystem: mingw64, msys-env: mingw-w64-x86_64 }
+ - { name: Linux, os: ubuntu-20.04, shell: sh }
+ - { name: Macos, os: macos-latest, shell: sh }
+
+
+ steps:
+ - uses: actions/checkout@v4
+ with:
+ submodules: recursive
+ - name: Set up Ninja
+ uses: ./.github/actions/setup-ninja
+ if: ${{ !contains(matrix.platform.shell, 'msys2') }}
+ - uses: ilammy/msvc-dev-cmd@v1
+ if: ${{ matrix.platform.msvc }}
+ with:
+ arch: x64
+ - name: Set up MSYS2
+ if: ${{ matrix.platform.shell == 'msys2 {0}' }}
+ uses: msys2/setup-msys2@v2
+ with:
+ msystem: ${{ matrix.platform.msystem }}
+ install: >-
+ ${{ matrix.platform.msys-env }}-cmake
+ ${{ matrix.platform.msys-env }}-gcc
+ ${{ matrix.platform.msys-env }}-ninja
+ - name: Set up SDL
+ id: sdl
+ uses: libsdl-org/setup-sdl@main
+ with:
+ cmake-generator: Ninja
+ version: 3-head
+ sdl-test: true
+ shell: ${{ matrix.platform.shell }}
+
+ - name: Configure (CMake)
+ run: |
+ cmake -S . -B build -GNinja -DBUILD_STATIC=ON -DBUILD_CLI=ON -DENABLE_WERROR=OFF -DCMAKE_POLICY_DEFAULT_CMP0074=NEW
+
+ - name: Build (CMake)
+ id: build
+ run: |
+ cmake --build build --config Release --parallel --verbose
diff --git a/CMakeLists.txt b/CMakeLists.txt
index 53cfae2..7d07a92 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,115 +1,190 @@
# CMake Project for SDL_gpu_shadercross - Simple DirectMedia Layer Shader Cross Compiler
# Written by @thatcosmonaut
-cmake_minimum_required(VERSION 3.5)
-project(SDL_gpu_shadercross C)
-find_package(SDL3 REQUIRED)
+cmake_minimum_required(VERSION 3.8)
+
+# Version
+set(MAJOR_VERSION "1")
+set(MINOR_VERSION "0")
+set(MICRO_VERSION "0")
+set(SDL_REQUIRED_VERSION "3.1.3")
+
+project(SDL_gpu_shadercross LANGUAGES C VERSION "${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}")
# Options
option(BUILD_STATIC "Build static library" ON)
option(BUILD_CLI "Build command line executable" ON)
+option(ENABLE_WERROR "Enable Werror" OFF)
+option(ENABLE_INSTALL "Enable installation" OFF)
-# Version
-SET(LIB_MAJOR_VERSION "1")
-SET(LIB_MINOR_VERSION "0")
-SET(LIB_REVISION "0")
-SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
-
-# Build Type
-if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
- # By default, we use Release
- message(STATUS "Setting build type to 'Release' as none was specified.")
- set(CMAKE_BUILD_TYPE "Release" CACHE
- STRING "Choose the type of build." FORCE
- )
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/PrivateSdlFunctions.cmake")
- # Set the possible values of build type for cmake-gui
- set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
- STRINGS "Debug" "Release" "RelWithDebInfo"
- )
-endif()
+sdl_calculate_derived_version_variables(${MAJOR_VERSION} ${MINOR_VERSION} ${MICRO_VERSION})
# Platform Flags
if(APPLE)
set(CMAKE_MACOSX_RPATH ON)
set(CMAKE_OSX_DEPLOYMENT_TARGET 11.0)
- set(LOBJC "objc")
-elseif(WIN32)
- # "SDL_gpu_shadercross.dll", not "libSDL_gpu_shadercross.dll"
- set(CMAKE_SHARED_LIBRARY_PREFIX "")
endif()
-# Source lists
+if(NOT MSVC)
+ add_compile_options(-pedantic) # -Wno-strict-aliasing
+endif()
-file(GLOB SOURCE_FILES
+# Source lists
+set(SOURCE_FILES
# Public Headers
- SDL_gpu_shadercross.h
+ include/SDL_gpu_shadercross.h
# Source Files
src/SDL_gpu_shadercross.c
src/spirv_cross_c.h
src/spirv.h
)
-add_library(SDL_gpu_shadercross SHARED ${SOURCE_FILES})
+find_package(SDL3 REQUIRED COMPONENTS SDL3-shared)
+
+add_library(SDL_gpu_shadercross-shared SHARED ${SOURCE_FILES})
+add_library(SDL_gpu_shadercross::SDL_gpu_shadercross ALIAS SDL_gpu_shadercross-shared)
+
+set_property(TARGET SDL_gpu_shadercross-shared PROPERTY DEFINE_SYMBOL DLL_EXPORT)
+sdl_add_warning_options(SDL_gpu_shadercross-shared WARNING_AS_ERROR ${ENABLE_WERROR})
+sdl_target_link_option_version_file(SDL_gpu_shadercross-shared "${CMAKE_CURRENT_SOURCE_DIR}/src/SDL_gpu_shadercross.sym")
# Build flags
-if(NOT MSVC)
- set_property(TARGET SDL_gpu_shadercross PROPERTY COMPILE_FLAGS "-std=gnu99 -Wall -Wno-strict-aliasing -pedantic")
+if(WIN32)
+ target_sources(SDL_gpu_shadercross-shared PRIVATE "src/version.rc")
+ set_property(TARGET SDL_gpu_shadercross-shared PROPERTY PREFIX "")
endif()
+target_compile_features(SDL_gpu_shadercross-shared PRIVATE c_std_99)
# SDL_gpu_shadercross folders as includes, for other targets to consume
-target_include_directories(SDL_gpu_shadercross PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
+target_include_directories(SDL_gpu_shadercross-shared PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
# MinGW builds should statically link libgcc
if(MINGW)
- target_link_libraries(SDL_gpu_shadercross PRIVATE -static-libgcc)
+ target_link_libraries(SDL_gpu_shadercross-shared PRIVATE -static-libgcc)
endif()
# Soname
-set_target_properties(SDL_gpu_shadercross PROPERTIES OUTPUT_NAME "SDL_gpu_shadercross"
- VERSION ${LIB_VERSION}
- SOVERSION ${LIB_MAJOR_VERSION}
+set_target_properties(SDL_gpu_shadercross-shared PROPERTIES OUTPUT_NAME "SDL_gpu_shadercross"
+ SOVERSION "${SO_VERSION_MAJOR}"
+ VERSION "${SO_VERSION}"
)
-target_link_libraries(SDL_gpu_shadercross PRIVATE
- SDL3::SDL3
- SDL3::Headers
+target_link_libraries(SDL_gpu_shadercross-shared PRIVATE
+ SDL3::SDL3-shared
)
if(BUILD_STATIC)
+ find_package(SDL3 REQUIRED COMPONENTS Headers)
+
add_library(SDL_gpu_shadercross-static STATIC ${SOURCE_FILES})
+ add_library(SDL_gpu_shadercross::SDL_gpu_shadercross-static ALIAS SDL_gpu_shadercross-static)
+ sdl_add_warning_options(SDL_gpu_shadercross-static WARNING_AS_ERROR ${ENABLE_WERROR})
+ target_compile_features(SDL_gpu_shadercross-static PRIVATE c_std_99)
- # Build flags
- if(NOT MSVC)
- set_property(TARGET SDL_gpu_shadercross-static PROPERTY COMPILE_FLAGS "-std=gnu99 -Wall -Wno-strict-aliasing -pedantic")
- endif()
+ if(NOT MSVC)
+ set_property(TARGET SDL_gpu_shadercross-static PROPERTY OUTPUT_NAME "SDL_gpu_shadercross")
+ endif()
# SDL_gpu_shadercross folders as includes, for other targets to consume
target_include_directories(SDL_gpu_shadercross-static PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
- # MinGW builds should statically link libgcc
- if(MINGW)
- target_link_libraries(SDL_gpu_shadercross-static PRIVATE -static-libgcc)
- endif()
-
- # Soname
- set_target_properties(SDL_gpu_shadercross-static PROPERTIES OUTPUT_NAME "SDL_gpu_shadercross-static"
- VERSION ${LIB_VERSION}
- SOVERSION ${LIB_MAJOR_VERSION}
- )
-
- target_link_libraries(SDL_gpu_shadercross-static PRIVATE
- SDL3::SDL3-static
+ target_link_libraries(SDL_gpu_shadercross-static PUBLIC
SDL3::Headers
)
endif()
+if(NOT TARGET SDL_gpu_shadercross::SDL_gpu_shadercross)
+ if(TARGET SDL_gpu_shadercross-shared)
+ add_library(SDL_gpu_shadercross::SDL_gpu_shadercross ALIAS SDL_gpu_shadercross-shared)
+ else()
+ add_library(SDL_gpu_shadercross::SDL_gpu_shadercross ALIAS SDL_gpu_shadercross-static)
+ endif()
+endif()
+
if(BUILD_CLI)
- file(GLOB CLI_SOURCES
- src/cli.c
- )
+ add_executable(shadercross src/cli.c)
+
+ target_link_libraries(shadercross PRIVATE SDL_gpu_shadercross::SDL_gpu_shadercross)
+ target_link_libraries(shadercross PRIVATE SDL3::SDL3)
+endif()
+
+if(ENABLE_INSTALL)
+ if(WIN32 AND NOT MINGW)
+ set(INSTALL_CMAKEDIR_ROOT_DEFAULT "cmake")
+ else()
+ set(INSTALL_CMAKEDIR_ROOT_DEFAULT "${CMAKE_INSTALL_LIBDIR}/cmake")
+ endif()
+ set(SDLGPUSHADERCROSS_INSTALL_CMAKEDIR_ROOT "${INSTALL_CMAKEDIR_ROOT_DEFAULT}" CACHE STRING "Root folder where to install SDL_gpu_shadercross cmake related files (SDL_gpu_shadercross subfolder for MSVC projects)")
+ set(SDLGPUSHADERCROSS_PKGCONFIG_INSTALLDIR "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
+
+ if(WIN32 AND NOT MINGW)
+ set(SDLGPUSHADERCROSS_INSTALL_CMAKEDIR "${SDLGPUSHADERCROSS_INSTALL_CMAKEDIR_ROOT}")
+ else()
+ set(SDLGPUSHADERCROSS_INSTALL_CMAKEDIR "${SDLGPUSHADERCROSS_INSTALL_CMAKEDIR_ROOT}/SDL_gpu_shadercross")
+ endif()
+
+ include(GNUInstallDirs)
+ if(TARGET SDL_gpu_shadercross-shared)
+ install(TARGETS SDL_gpu_shadercross-shared EXPORT SDL_gpu_shadercross-shared-export
+ ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT devel
+ LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT library
+ RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}" COMPONENT library
+ )
+ install(EXPORT SDL_gpu_shadercross-shared-export
+ FILE SDL_gpu_shadercross-shared-targets.cmake
+ NAMESPACE SDL_gpu_shadercross::
+ DESTINATION "${SDLGPUSHADERCROSS_INSTALL_CMAKEDIR}"
+ COMPONENT devel
+ )
+ endif()
+ if(TARGET SDL_gpu_shadercross-static)
+ install(TARGETS SDL_gpu_shadercross-static EXPORT SDL_gpu_shadercross-static-export
+ ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT devel
+ LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT library
+ )
+ install(EXPORT SDL_gpu_shadercross-static-export
+ FILE SDL_gpu_shadercross-static-targets.cmake
+ NAMESPACE SDL_gpu_shadercross::
+ DESTINATION "${SDLGPUSHADERCROSS_INSTALL_CMAKEDIR}"
+ COMPONENT devel
+ )
+ endif()
+ install(
+ FILES "${CMAKE_CURRENT_SOURCE_DIR}/include/SDL_gpu_shadercross.h"
+ DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}" COMPONENT DEVEL
+ )
+
+ include(CMakePackageConfigHelpers)
+ configure_package_config_file(cmake/SDL_gpu_shadercrossConfig.cmake.in SDL_gpu_shadercrossConfig.cmake
+ NO_SET_AND_CHECK_MACRO
+ INSTALL_DESTINATION "${SDLGPUSHADERCROSS_INSTALL_CMAKEDIR}"
+ )
+ write_basic_package_version_file("${PROJECT_BINARY_DIR}/SDL_gpu_shadercrossConfigVersion.cmake"
+ COMPATIBILITY AnyNewerVersion
+ )
+ install(
+ FILES
+ "${CMAKE_CURRENT_BINARY_DIR}/SDL_gpu_shadercrossConfig.cmake"
+ "${CMAKE_CURRENT_BINARY_DIR}/SDL_gpu_shadercrossConfigVersion.cmake"
+ DESTINATION "${SDLGPUSHADERCROSS_INSTALL_CMAKEDIR}"
+ COMPONENT devel
+ )
+
+ file(RELATIVE_PATH SDL_PATH_PREFIX_RELATIVE_TO_PKGCONFIG "${CMAKE_INSTALL_PREFIX}/${SDLGPUSHADERCROSS_PKGCONFIG_INSTALLDIR}" "${CMAKE_INSTALL_PREFIX}")
+ string(REGEX REPLACE "[/]+$" "" SDL_PATH_PREFIX_RELATIVE_TO_PKGCONFIG "${SDL_PATH_PREFIX_RELATIVE_TO_PKGCONFIG}")
+ set(SDL_PKGCONFIG_PREFIX "\${pcfiledir}/${SDL_PATH_PREFIX_RELATIVE_TO_PKGCONFIG}")
+ set(PC_REQUIRED "")
+ set(PC_LIBS "")
+ configure_file(cmake/sdl-gpu-shadercross.pc.in sdl-gpu-shadercross.pc @ONLY)
- add_executable(shadercross ${CLI_SOURCES})
+ # Always install sdl-gpu-shadercross.pc file: libraries might be different between config modes
+ install(FILES "${CMAKE_CURRENT_BINARY_DIR}/sdl-gpu-shadercross.pc"
+ DESTINATION "${SDLGPUSHADERCROSS_PKGCONFIG_INSTALLDIR}" COMPONENT devel)
+
+ install(FILES "LICENSE.txt"
+ DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/licenses/${PROJECT_NAME}"
+ COMPONENT library
+ )
- target_link_libraries(shadercross PRIVATE SDL3::SDL3-static SDL3::Headers)
- target_link_libraries(shadercross PRIVATE SDL_gpu_shadercross-static)
endif()
diff --git a/cmake/PrivateSdlFunctions.cmake b/cmake/PrivateSdlFunctions.cmake
new file mode 100644
index 0000000..0bd77bb
--- /dev/null
+++ b/cmake/PrivateSdlFunctions.cmake
@@ -0,0 +1,355 @@
+# This file is shared amongst SDL_image/SDL_mixer/SDL_ttf
+
+include(CheckCCompilerFlag)
+include(CheckCSourceCompiles)
+include(CMakePushCheckState)
+
+macro(sdl_calculate_derived_version_variables MAJOR MINOR MICRO)
+ set(SO_VERSION_MAJOR "0")
+ set(SO_VERSION_MINOR "${MINOR_VERSION}")
+ set(SO_VERSION_MICRO "${MICRO_VERSION}")
+ set(SO_VERSION "${SO_VERSION_MAJOR}.${SO_VERSION_MINOR}.${SO_VERSION_MICRO}")
+
+ if(MINOR MATCHES "[02468]$")
+ math(EXPR DYLIB_COMPAT_VERSION_MAJOR "100 * ${MINOR} + 1")
+ set(DYLIB_COMPAT_VERSION_MINOR "0")
+ math(EXPR DYLIB_CURRENT_VERSION_MAJOR "${DYLIB_COMPAT_VERSION_MAJOR}")
+ set(DYLIB_CURRENT_VERSION_MINOR "${MICRO}")
+ else()
+ math(EXPR DYLIB_COMPAT_VERSION_MAJOR "100 * ${MINOR} + ${MICRO} + 1")
+ set(DYLIB_COMPAT_VERSION_MINOR "0")
+ math(EXPR DYLIB_CURRENT_VERSION_MAJOR "${DYLIB_COMPAT_VERSION_MAJOR}")
+ set(DYLIB_CURRENT_VERSION_MINOR "0")
+ endif()
+ set(DYLIB_COMPAT_VERSION_MICRO "0")
+ set(DYLIB_CURRENT_VERSION_MICRO "0")
+
+ set(DYLIB_CURRENT_VERSION "${DYLIB_CURRENT_VERSION_MAJOR}.${DYLIB_CURRENT_VERSION_MINOR}.${DYLIB_CURRENT_VERSION_MICRO}")
+ set(DYLIB_COMPAT_VERSION "${DYLIB_COMPAT_VERSION_MAJOR}.${DYLIB_COMPAT_VERSION_MINOR}.${DYLIB_COMPAT_VERSION_MICRO}")
+endmacro()
+
+function(read_absolute_symlink DEST PATH)
+ file(READ_SYMLINK "${PATH}" p)
+ if(NOT IS_ABSOLUTE "${p}")
+ get_filename_component(pdir "${PATH}" DIRECTORY)
+ set(p "${pdir}/${p}")
+ endif()
+ get_filename_component(p "${p}" ABSOLUTE)
+ set("${DEST}" "${p}" PARENT_SCOPE)
+endfunction()
+
+function(win32_implib_identify_dll DEST IMPLIB)
+ cmake_parse_arguments(ARGS "NOTFATAL" "" "" ${ARGN})
+ if(CMAKE_DLLTOOL)
+ execute_process(
+ COMMAND "${CMAKE_DLLTOOL}" --identify "${IMPLIB}"
+ RESULT_VARIABLE retcode
+ OUTPUT_VARIABLE stdout
+ ERROR_VARIABLE stderr)
+ if(NOT retcode EQUAL 0)
+ if(NOT ARGS_NOTFATAL)
+ message(FATAL_ERROR "${CMAKE_DLLTOOL} failed.")
+ else()
+ set("${DEST}" "${DEST}-NOTFOUND" PARENT_SCOPE)
+ return()
+ endif()
+ endif()
+ string(STRIP "${stdout}" result)
+ set(${DEST} "${result}" PARENT_SCOPE)
+ elseif(MSVC)
+ get_filename_component(CMAKE_C_COMPILER_DIRECTORY "${CMAKE_C_COMPILER}" DIRECTORY CACHE)
+ find_program(CMAKE_DUMPBIN NAMES dumpbin PATHS "${CMAKE_C_COMPILER_DIRECTORY}")
+ if(CMAKE_DUMPBIN)
+ execute_process(
+ COMMAND "${CMAKE_DUMPBIN}" "-headers" "${IMPLIB}"
+ RESULT_VARIABLE retcode
+ OUTPUT_VARIABLE stdout
+ ERROR_VARIABLE stderr)
+ if(NOT retcode EQUAL 0)
+ if(NOT ARGS_NOTFATAL)
+ message(FATAL_ERROR "dumpbin failed.")
+ else()
+ set(${DEST} "${DEST}-NOTFOUND" PARENT_SCOPE)
+ return()
+ endif()
+ endif()
+ string(REGEX MATCH "DLL name[ ]+:[ ]+([^\n]+)\n" match "${stdout}")
+ if(NOT match)
+ if(NOT ARGS_NOTFATAL)
+ message(FATAL_ERROR "dumpbin did not find any associated dll for ${IMPLIB}.")
+ else()
+ set(${DEST} "${DEST}-NOTFOUND" PARENT_SCOPE)
+ return()
+ endif()
+ endif()
+ set(result "${CMAKE_MATCH_1}")
+ set(${DEST} "${result}" PARENT_SCOPE)
+ else()
+ message(FATAL_ERROR "Cannot find dumpbin, please set CMAKE_DUMPBIN cmake variable")
+ endif()
+ else()
+ if(NOT ARGS_NOTFATAL)
+ message(FATAL_ERROR "Don't know how to identify dll from import library. Set CMAKE_DLLTOOL (for mingw) or CMAKE_DUMPBIN (for MSVC)")
+ else()
+ set(${DEST} "${DEST}-NOTFOUND")
+ endif()
+ endif()
+endfunction()
+
+function(get_actual_target)
+ set(dst "${ARGV0}")
+ set(target "${${dst}}")
+ set(input "${target}")
+ get_target_property(alias "${target}" ALIASED_TARGET)
+ while(alias)
+ set(target "${alias}")
+ get_target_property(alias "${target}" ALIASED_TARGET)
+ endwhile()
+ message(DEBUG "get_actual_target(\"${input}\") -> \"${target}\"")
+ set("${dst}" "${target}" PARENT_SCOPE)
+endfunction()
+
+function(target_get_dynamic_library DEST TARGET)
+ set(result)
+ get_actual_target(TARGET)
+ if(WIN32)
+ # Use the target dll of the import library
+ set(props_to_check IMPORTED_IMPLIB)
+ if(CMAKE_BUILD_TYPE)
+ list(APPEND props_to_check IMPORTED_IMPLIB_${CMAKE_BUILD_TYPE})
+ endif()
+ list(APPEND props_to_check IMPORTED_LOCATION)
+ if(CMAKE_BUILD_TYPE)
+ list(APPEND props_to_check IMPORTED_LOCATION_${CMAKE_BUILD_TYPE})
+ endif()
+ foreach (config_type ${CMAKE_CONFIGURATION_TYPES} RELEASE DEBUG RELWITHDEBINFO MINSIZEREL)
+ list(APPEND props_to_check IMPORTED_IMPLIB_${config_type})
+ list(APPEND props_to_check IMPORTED_LOCATION_${config_type})
+ endforeach()
+
+ foreach(prop_to_check ${props_to_check})
+ if(NOT result)
+ get_target_property(propvalue "${TARGET}" ${prop_to_check})
+ if(propvalue AND EXISTS "${propvalue}")
+ win32_implib_identify_dll(result "${propvalue}" NOTFATAL)
+ endif()
+ endif()
+ endforeach()
+ else()
+ # 1. find the target library a file might be symbolic linking to
+ # 2. find all other files in the same folder that symolic link to it
+ # 3. sort all these files, and select the 1st item on Linux, and last on Macos
+ set(location_properties IMPORTED_LOCATION)
+ if(CMAKE_BUILD_TYPE)
+ list(APPEND location_properties IMPORTED_LOCATION_${CMAKE_BUILD_TYPE})
+ endif()
+ foreach (config_type ${CMAKE_CONFIGURATION_TYPES} RELEASE DEBUG RELWITHDEBINFO MINSIZEREL)
+ list(APPEND location_properties IMPORTED_LOCATION_${config_type})
+ endforeach()
+ if(APPLE)
+ set(valid_shared_library_regex "\\.[0-9]+\\.dylib$")
+ else()
+ set(valid_shared_library_regex "\\.so\\.([0-9.]+)?[0-9]")
+ endif()
+ foreach(location_property ${location_properties})
+ if(NOT result)
+ get_target_property(library_path "${TARGET}" ${location_property})
+ message(DEBUG "get_target_property(${TARGET} ${location_propert}) -> ${library_path}")
+ if(EXISTS "${library_path}")
+ get_filename_component(library_path "${library_path}" ABSOLUTE)
+ while (IS_SYMLINK "${library_path}")
+ read_absolute_symlink(library_path "${library_path}")
+ endwhile()
+ message(DEBUG "${TARGET} -> ${library_path}")
+ get_filename_component(libdir "${library_path}" DIRECTORY)
+ file(GLOB subfiles "${libdir}/*")
+ set(similar_files "${library_path}")
+ foreach(subfile ${subfiles})
+ if(IS_SYMLINK "${subfile}")
+ read_absolute_symlink(subfile_target "${subfile}")
+ while(IS_SYMLINK "${subfile_target}")
+ read_absolute_symlink(subfile_target "${subfile_target}")
+ endwhile()
+ get_filename_component(subfile_target "${subfile_target}" ABSOLUTE)
+ if(subfile_target STREQUAL library_path AND subfile MATCHES "${valid_shared_library_regex}")
+ list(APPEND similar_files "${subfile}")
+ endif()
+ endif()
+ endforeach()
+ list(SORT similar_files)
+ message(DEBUG "files that are similar to \"${library_path}\"=${similar_files}")
+ if(APPLE)
+ list(REVERSE similar_files)
+ endif()
+ list(GET similar_files 0 item)
+ get_filename_component(result "${item}" NAME)
+ endif()
+ endif()
+ endforeach()
+ endif()
+ if(result)
+ string(TOLOWER "${result}" result_lower)
+ if(WIN32 OR OS2)
+ if(NOT result_lower MATCHES ".*dll")
+ message(FATAL_ERROR "\"${result}\" is not a .dll library")
+ endif()
+ elseif(APPLE)
+ if(NOT result_lower MATCHES ".*dylib.*")
+ message(FATAL_ERROR "\"${result}\" is not a .dylib shared library")
+ endif()
+ else()
+ if(NOT result_lower MATCHES ".*so.*")
+ message(FATAL_ERROR "\"${result}\" is not a .so shared library")
+ endif()
+ endif()
+ else()
+ get_target_property(target_type ${TARGET} TYPE)
+ if(target_type MATCHES "SHARED_LIBRARY|MODULE_LIBRARY")
+ # OK
+ elseif(target_type MATCHES "STATIC_LIBRARY|OBJECT_LIBRARY|INTERFACE_LIBRARY|EXECUTABLE")
+ message(SEND_ERROR "${TARGET} is not a shared library, but has type=${target_type}")
+ else()
+ message(WARNING "Unable to extract dynamic library from target=${TARGET}, type=${target_type}.")
+ endif()
+ # TARGET_SONAME_FILE is not allowed for DLL target platforms.
+ if(WIN32)
+ set(result "$<TARGET_FILE_NAME:${TARGET}>")
+ else()
+ set(result "$<TARGET_SONAME_FILE_NAME:${TARGET}>")
+ endif()
+ endif()
+ set(${DEST} ${result} PARENT_SCOPE)
+endfunction()
+
+function(sdl_check_project_in_subfolder relative_subfolder name vendored_option)
+ cmake_parse_arguments(ARG "" "FILE" "" ${ARGN})
+ if(NOT ARG_FILE)
+ set(ARG_FILE "CMakeLists.txt")
+ endif()
+ if(NOT EXISTS "${PROJECT_SOURCE_DIR}/${relative_subfolder}/${ARG_FILE}")
+ message(FATAL_ERROR "Could not find ${ARG_FILE} for ${name} in ${relative_subfolder}.\n"
+ "Run the download script in the external folder, or re-configure with -D${vendored_option}=OFF to use system packages.")
+ endif()
+endfunction()
+
+macro(sdl_check_linker_flag flag var)
+ # FIXME: Use CheckLinkerFlag module once cmake minimum version >= 3.18
+ cmake_push_check_state(RESET)
+ set(CMAKE_REQUIRED_LINK_OPTIONS "${flag}")
+ check_c_source_compiles("int main() { return 0; }" ${var} FAIL_REGEX "(unsupported|syntax error|unrecognized option)")
+ cmake_pop_check_state()
+endmacro()
+
+function(SDL_detect_linker)
+ if(CMAKE_VERSION VERSION_LESS 3.29)
+ if(NOT DEFINED SDL_CMAKE_C_COMPILER_LINKER_ID)
+ execute_process(COMMAND ${CMAKE_LINKER} -v OUTPUT_VARIABLE LINKER_OUTPUT ERROR_VARIABLE LINKER_OUTPUT)
+ string(REGEX REPLACE "[\r\n]" " " LINKER_OUTPUT "${LINKER_OUTPUT}")
+ if(LINKER_OUTPUT MATCHES ".*Microsoft.*")
+ set(linker MSVC)
+ else()
+ set(linker GNUlike)
+ endif()
+ message(STATUS "Linker identification: ${linker}")
+ set(SDL_CMAKE_C_COMPILER_LINKER_ID "${linker}" CACHE STRING "Linker identification")
+ mark_as_advanced(SDL_CMAKE_C_COMPILER_LINKER_ID)
+ endif()
+ set(CMAKE_C_COMPILER_LINKER_ID "${SDL_CMAKE_C_COMPILER_LINKER_ID}" PARENT_SCOPE)
+ endif()
+endfunction()
+
+function(check_linker_support_version_script VAR)
+ SDL_detect_linker()
+ if(CMAKE_C_COMPILER_LINKER_ID MATCHES "^(MSVC)$")
+ set(LINKER_SUPPORTS_VERSION_SCRIPT FALSE)
+ else()
+ cmake_push_check_state(RESET)
+ file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/dummy.sym" "n_0 {\n global:\n func;\n local: *;\n};\n")
+ list(APPEND CMAKE_REQUIRED_LINK_OPTIONS "-Wl,--version-script=${CMAKE_CURRENT_BINARY_DIR}/dummy.sym")
+ check_c_source_compiles("int func(void) {return 0;} int main(int argc,char*argv[]){(void)argc;(void)argv;return func();}" LINKER_SUPPORTS_VERSION_SCRIPT FAIL_REGEX "(unsupported|syntax error|unrecognized option)")
+ cmake_pop_check_state()
+ endif()
+ set(${VAR} "${LINKER_SUPPORTS_VERSION_SCRIPT}" PARENT_SCOPE)
+endfunction()
+
+function(sdl_target_link_options_no_undefined TARGET)
+ if(NOT MSVC)
+ if(CMAKE_C_COMPILER_ID MATCHES "AppleClang")
+ target_link_options(${TARGET} PRIVATE "-Wl,-undefined,error")
+ else()
+ sdl_check_linker_flag("-Wl,--no-undefined" HAVE_WL_NO_UNDEFINED)
+ if(HAVE_WL_NO_UNDEFINED AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") AND WIN32))
+ target_link_options(${TARGET} PRIVATE "-Wl,--no-undefined")
+ endif()
+ endif()
+ endif()
+endfunction()
+
+function(sdl_target_link_option_version_file TARGET VERSION_SCRIPT)
+ check_linker_support_version_script(HAVE_WL_VERSION_SCRIPT)
+ if(HAVE_WL_VERSION_SCRIPT)
+ target_link_options(${TARGET} PRIVATE "-Wl,--version-script=${VERSION_SCRIPT}")
+ set_property(TARGET ${TARGET} APPEND PROPERTY LINK_DEPENDS "${VERSION_SCRIPT}")
+ else()
+ if(LINUX OR ANDROID)
+ message(FATAL_ERROR "Linker does not support '-Wl,--version-script=xxx.sym'. This is required on the current host platform.")
+ endif()
+ endif()
+endfunction()
+
+function(sdl_add_warning_options TARGET)
+ cmake_parse_arguments(ARGS "" "WARNING_AS_ERROR" "" ${ARGN})
+ if(MSVC)
+ target_compile_options(${TARGET} PRIVATE /W2)
+ else()
+ target_compile_options(${TARGET} PRIVATE -Wall -Wextra)
+ endif()
+ if(ARGS_WARNING_AS_ERROR)
+ if(MSVC)
+ target_compile_options(${TARGET} PRIVATE /WX)
+ else()
+ target_compile_options(${TARGET} PRIVATE -Werror)
+ endif()
+ endif()
+endfunction()
+
+function(sdl_no_deprecated_errors TARGET)
+ check_c_compiler_flag(-Wno-error=deprecated-declarations HAVE_WNO_ERROR_DEPRECATED_DECLARATIONS)
+ if(HAVE_WNO_ERROR_DEPRECATED_DECLARATIONS)
+ target_compile_options(${TARGET} PRIVATE "-Wno-error=deprecated-declarations")
+endif()
+endfunction()
+
+function(sdl_get_git_revision_hash VARNAME)
+ set("${VARNAME}" "" CACHE STRING "${PROJECT_NAME} revision")
+ set(revision "${${VARNAME}}")
+ if(NOT revision)
+ if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/VERSION.txt")
+ # If VERSION.txt exists, it contains the SDL version
+ file(READ "${CMAKE_CURRENT_SOURCE_DIR}/VERSION.txt" revision_version)
+ string(STRIP "${revision_version}" revision_version)
+ else()
+ # If VERSION.txt does not exist, use git to calculate a version
+ git_describe(revision_version)
+ if(NOT revision_version)
+ set(revision_version "${PROJECT_VERSION}-no-vcs")
+ endif()
+ endif()
+ set(revision "${revision_version}")
+ endif()
+ set("${VARNAME}" "${revision}" PARENT_SCOPE)
+endfunction()
+
+function(SDL_install_pdb TARGET DIRECTORY)
+ get_property(type TARGET ${TARGET} PROPERTY TYPE)
+ if(type MATCHES "^(SHARED_LIBRARY|EXECUTABLE)$")
+ install(FILES $<TARGET_PDB_FILE:${TARGET}> DESTINATION "${DIRECTORY}" OPTIONAL)
+ elseif(type STREQUAL "STATIC_LIBRARY")
+ # FIXME: Use $<TARGET_COMPILE_PDB_FILE:${TARGET} once it becomes available (https://gitlab.kitware.com/cmake/cmake/-/issues/25244)
+ if(CMAKE_GENERATOR MATCHES "^Visual Studio.*")
+ install(CODE "file(INSTALL DESTINATION \"\${CMAKE_INSTALL_PRE
(Patch may be truncated, please check the link at the top of this post.)